ccan/ccan/tdb/tools/keywords.gperf

%{
%}
%language=ANSI-C
struct op_table {
	const char *name;
	enum op_type type;
	void (*enhance_op)(const char *filename,
			   struct op op[], unsigned int op_num, char *words[]);
};
%define hash-function-name hash_keyword
%define lookup-function-name find_keyword
%readonly-tables
%struct-type
%enum
%%
tdb_lockall, OP_TDB_LOCKALL, op_add_nothing,
tdb_lockall_mark, OP_TDB_LOCKALL_MARK, op_add_nothing,
tdb_lockall_unmark, OP_TDB_LOCKALL_UNMARK, op_add_nothing,
tdb_lockall_nonblock, OP_TDB_LOCKALL_NONBLOCK, op_add_nothing,
tdb_unlockall, OP_TDB_UNLOCKALL, op_add_nothing,
tdb_lockall_read, OP_TDB_LOCKALL_READ, op_add_nothing,
tdb_lockall_read_nonblock, OP_TDB_LOCKALL_READ_NONBLOCK, op_add_nothing,
tdb_unlockall_read, OP_TDB_UNLOCKALL_READ, op_add_nothing,
tdb_chainlock, OP_TDB_CHAINLOCK, op_add_key,
tdb_chainlock_nonblock, OP_TDB_CHAINLOCK_NONBLOCK, op_add_key_ret,
tdb_chainlock_mark, OP_TDB_CHAINLOCK_MARK, op_add_key,
tdb_chainlock_unmark, OP_TDB_CHAINLOCK_UNMARK, op_add_key,
tdb_chainunlock, OP_TDB_CHAINUNLOCK, op_add_key,
tdb_chainlock_read, OP_TDB_CHAINLOCK_READ, op_add_key,
tdb_chainunlock_read, OP_TDB_CHAINUNLOCK_READ, op_add_key,
tdb_increment_seqnum_nonblock, OP_TDB_INCREMENT_SEQNUM_NONBLOCK, op_add_nothing,
tdb_parse_record, OP_TDB_PARSE_RECORD, op_add_key_ret,
tdb_exists, OP_TDB_EXISTS, op_add_key_ret,
tdb_store, OP_TDB_STORE, op_add_store,
tdb_append, OP_TDB_APPEND, op_add_append,
tdb_get_seqnum, OP_TDB_GET_SEQNUM, op_add_seqnum,
tdb_wipe_all, OP_TDB_WIPE_ALL, op_add_nothing,
tdb_transaction_start, OP_TDB_TRANSACTION_START, op_add_nothing,
tdb_transaction_cancel, OP_TDB_TRANSACTION_CANCEL, op_add_nothing,
tdb_transaction_commit, OP_TDB_TRANSACTION_COMMIT, op_add_nothing,
tdb_traverse_read_start, OP_TDB_TRAVERSE_READ_START, op_add_traverse,
tdb_traverse_start, OP_TDB_TRAVERSE_START, op_add_traverse,
tdb_traverse_end, OP_TDB_TRAVERSE_END, op_analyze_traverse,
traverse, OP_TDB_TRAVERSE, op_add_key_data,
tdb_firstkey, OP_TDB_FIRSTKEY, op_add_key,
tdb_nextkey, OP_TDB_NEXTKEY, op_add_key_data,
tdb_fetch, OP_TDB_FETCH, op_add_key_data,
tdb_delete, OP_TDB_DELETE, op_add_key_ret,